Arch Linux User Repository

Hi there. Your PKGBUILD seems a bit rushed.

v0.5.0.r6.g7ccc7035

You should generate the version without that leading v. It's more clean and an actual higher number if you would upgrade from oomd. (0.5.0 > 0.4.0 > v0.5.0). Also your current version in your PKGBUILD is higher then what what the package is after the building process. (PKGBUILD is v0.5.0.r6.g7ccc7035 > Package is: v0.5.0.r6.g7ccc703)

depends=('jsoncpp')
makedepends=('meson' 'ninja' 'git' 'jsoncpp')

There is no need to specify jsoncpp in make- and in depends. makedepends always include depends. On top of that ninja isn't necessary here.

source=(
    "oomd::git+https://github.com/facebookincubator/oomd.git"
)

I can't tell what this is. Is there a reason for it?

The cleaned up PKGBUILD:

# Maintainer: Jianqiu Zhang <void001@archlinuxcn.org>
# Maintainer: Solomon Choina <shlomochoina@gmail.com>
# Contributor: Fabian Bornschein <fabiscafe-cat-mailbox-dog-org>

pkgname=oomd-git
pkgver=0.5.0+6+g7ccc703
pkgrel=1
pkgdesc='A userspace out-of-memory killer'
arch=('x86_64')
url="https://github.com/facebookincubator/oomd"
license=('GPL2')
depends=('jsoncpp')
makedepends=('meson' 'git')
source=("git+https://github.com/facebookincubator/oomd.git")
sha256sums=('SKIP')

pkgver() {
  cd oomd
  git describe --tags | sed 's/^v//;s/-/+/g'
}

build() {
  arch-meson oomd build
  meson compile -C build
}

package() {
  meson install -C build --destdir "${pkgdir}"
  install -Dm644 "${srcdir}/oomd/src/oomd/etc/desktop.json" "${pkgdir}/etc/oomd/desktop.json.example"
}

I think the package version is wrong. pkgver says v0.5.0.r6.g7ccc7035 but the git describe command returns v0.5.0.r6.g7ccc703, which causes a mismatch between the installed version and the advertised version, which causes some AUR helpers to think it's constantly outdated. Maybe the version number could be updated?

Line 35 in the PKGBUILD is incorrect:

install -Dm644 $srcdir/oomd/etc/desktop.json $pkgdir/etc/desktop.json.example

should be:

install -Dm644 $srcdir/oomd/src/oomd/etc/desktop.json $pkgdir/etc/desktop.json.example

Patch is no longer required.. https://github.com/facebookincubator/oomd/blob/master/meson.build

==> Rozpoczynanie prepare()...
Fix the install patch error
can't find file to patch at input line 5