Arch Linux User Repository

@titmouse84 Thank you for the build fix! I implemented it although the include statement had to be #include <algorithm.

@dreieck Thank you for reporting the build issue upstream. It has been fixed since then, so I will delete the fix in the next version.

this has now been reported upstream:

This should resolve the std::shuffle error

Until upstream has fixed it, I propose as a workaround to add a patch to this package that fixes it locally.

Navigate to the directory containing the source code:

cd ~/.cache/paru/clone/tacentview/src/build/_deps/tacent-src/Modules/Image/Src/

Open tQuantizeSpatial.cpp in text editor:

nano tQuantizeSpatial.cpp

Add the following line near the top of the file, along with other include statements:

include <algorithm>

Save the file and exit the editor.

Rebuild the package:

cd ~/.cache/paru/clone/tacentview/ makepkg -si This should resolve the std::shuffle error and allow the build process to proceed.

The gcc-libs depend is already required by the base package so isn't it safe to assume that people using AUR already have it installed?

You are right.

The gcc-libs depend is already required by the base package so isn't it safe to assume that people using AUR already have it installed? Similar to base-devel.

@dreieck Thank you.

↗ Here is a PKGBUILD that solves some issues with the package (there were also other spurious installation directories present) and simplifies some stuff, and also installs documentation:

# Maintainer:  begin-theadventure <begin-thecontact.ncncb at dralias dot com>
# Contributor: drieck (https://aur.archlinux.org/account/dreieck)
# Contributor: frousties

_pkgname=tacentview
pkgname="${_pkgname}"
pkgver=1.0.43
pkgrel=2
pkgdesc="An image and texture viewer for tga, png, apng, exr, dds, ktx, ktx2, astc, pkm, qoi, gif, hdr, jpg, tif, ico, webp, and bmp files. Uses Dear ImGui, OpenGL and Tacent"
arch=('x86_64')
url="https://github.com/bluescan/tacentview"
license=('ISC')
depends=('gcc-libs' 'glibc' 'hicolor-icon-theme' 'libx11' 'libxcb')
# dpkg is needed since only building a debian package creates a installation-ready directory structure :-(.
makedepends=('cmake' 'dpkg' 'git' 'ninja')
source=(
  "${_pkgname}::git+${url}.git#tag=v${pkgver}"
)
sha256sums=(
  'SKIP'  # `tacentview` git
)

prepare() {
  cd "${srcdir}"

  mkdir -p build

  ## `cmake` call in `prepare()` since it will download stuff.
  cmake -S "${_pkgname}" -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DFETCHCONTENT_QUIET=OFF \
    -DPACKAGE_DEB=ON \
    -GNinja
}

build() {
  cd "${srcdir}"

  ninja -C build
  ninja -C build install # This is in `build()` and not in `package()` to workaround otherwise nested fakeroot error: `ninja -C build install` also calls fakeroot implicitly because it builds a .deb package, and this is needed to get the correct installation directories.
}

package() {
  cd "${srcdir}"

  cp -rv "build/ViewerInstall/Package/${_pkgname}_$(sed -E 's|\.([^\.]*)$|-\1|' <<<"${pkgver}")"/usr "${pkgdir}"/
  find "${pkgdir}" -name .gitignore -exec rm -v {} \;

  install -Dvm644 -t "${pkgdir}/usr/share/doc/${_pkgname}" "${_pkgname}/README.md"
  cp -rv "${_pkgname}/docs" "${pkgdir}/usr/share/doc/${_pkgname}"/

  install -Dvm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${_pkgname}/LICENSE"
  ln -svr "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE" "${pkgdir}/usr/share/doc/${_pkgname}/LICENSE"
}

Regards!

libxcb and hicolor-icon-theme are needed as dependencies.

And you must install the License file.

For me, now build works well with up to date GCC 13.2.1.

You can remove gcc12 from makedepends, and from the cmake options.

Regards!

In package(), you use ${_pkgname}, but this variable is not defined.

Also, you use $INPUT, but user defined variables in PKGBUILDs must start with an underscore (_).

Regards and thanks for maintaining!