Package Details: tailord 0.2.5-1

Git Clone URL: https://aur.archlinux.org/tailord.git (read-only, click to copy)
Package Base: tailord
Description: Daemon handling fan, keyboard and general HW support for Tuxedo laptops (part of tuxedo-rs)
Upstream URL: https://github.com/AaronErhardt/tuxedo-rs
Keywords: tuxedo tuxedo-rs
Licenses: GPL-2.0-or-later
Groups: tuxedo-rs
Conflicts: tuxedo-control-center
Provides: tailord
Submitter: tskaar
Maintainer: tskaar
Last Packager: tskaar
Votes: 2
Popularity: 0.000339
First Submitted: 2023-11-19 16:49 (UTC)
Last Updated: 2024-04-02 20:32 (UTC)

Dependencies (9)

Sources (1)

Latest Comments

tskaar commented on 2024-04-02 20:41 (UTC)

Hi, @evorster!

Thanks for letting me know about that git issue, I'll be a bit more consistent about having to rebuild tailord with the other packages (if there are any non-tagged commits that are required).

I pinned the tailord dependency to this specific version as a secondary 'safety' atleast for now.

Thanks for the feedback!

evorster commented on 2024-04-01 16:20 (UTC)

I've hacked the tailord package to use the same source as the tailor-gui. It may be possible to just use the same git commit for all the packages. 

# Maintainer: Torleif Skår <torleif.skaar AT gmail DOT com>
pkgname=tailord
pkgver="0.2.4"
pkgrel=1
pkgdesc="Daemon handling fan, keyboard and general HW support for Tuxedo laptops (part of tuxedo-rs)"
arch=("x86_64")
url="https://github.com/AaronErhardt/tuxedo-rs"
license=('GPL2')
groups=('tuxedo-rs')
provides=(
  'tailord'
)
depends=(
  'glibc'
  'gcc-libs'
  'tuxedo-io'
  'tuxedo-keyboard'
)
makedepends=(
  'git'
  'cargo'
)
optdepends=(
  'tailor-cli: CLI for controlling the daemon'
  'tailor-gui: GUI for controlling the daemon'
  'tailor-hwcaps: CLI tool for checking hardware capabilities'
)
conflicts=(
  'tuxedo-control-center'
)

_commit_hash="fcca331" # v0.2.3 w/latest dependencies
source=(
  "${pkgname}-${pkgver}"::"git+${url}#commit=${_commit_hash}"
)
sha256sums=('SKIP')
_archive="${pkgname}-${pkgver}"
_srcname="tailord"


prepare() {
  export RUSTUP_TOOLCHAIN=stable

  cd "${_archive}"

  # Fixup systemd service for tailord
  sed -e 's|ExecStart=.*|ExecStart=/usr/bin/tailord|' "${pkgname}/tailord.service.in" > "${pkgname}/tailord.service"

  # Fetch packages
  cargo fetch --locked --target "${CARCH}-unknown-linux-gnu" --manifest-path "${pkgname}/Cargo.toml"
}

build() {
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target

  cd "${_archive}"
  cargo build --frozen --release --all-features --manifest-path "${pkgname}/Cargo.toml"
}

package() {
  cd "${_archive}"

  install -Dm0755 -t "${pkgdir}/usr/bin" "target/release/${pkgname}"
  install -Dm0644 -t "${pkgdir}/usr/share/dbus-1/system.d/" "${pkgname}/com.tux.Tailor.conf"
  install -Dm0644 -t "${pkgdir}/usr/lib/systemd/system" "${pkgname}/tailord.service"
}

# vim: sw=2 ts=2 et:

evorster commented on 2024-04-01 16:18 (UTC)

Hi there!

Have a look at https://github.com/AaronErhardt/tuxedo-rs/issues/68 please. It seems that there is an issue when the sources for the various tailor packages get out of sync. Also, there is a new tag to try and harmonize the sources for now.

However, if you could update the various tailor packages to use exactly the same source, it would avoid us running into this type of issue in the future.

Thanks for making this package, by the way!

tskaar commented on 2023-11-27 17:56 (UTC)

Hi!

Upstream diverged the different cargo packages such that they have split version. Split PKGBUILD scripts doesn't allow the split packages to have different versions, hence I split them all into separate packages instead.

It's a bit messy overall (Ideally could've have built tuxedo-rs with the lowest common denominator or something)

evorster commented on 2023-11-27 09:32 (UTC)

Hi there!

What happened to tuxedo-rs? I see in the package description that this and three other packages are part of tuxedo-rs, and Google has a memory of such a package existing in the AUR, but right now there is none.