Arch Linux User Repository

When reporting this package as outdated make sure there is indeed a new version for Linux Desktop. You can have a look at the "Stable updates" tag in Release blog for this.

You can also run this command to obtain the version string for the latest chrome version:

$ curl -sSf https://dl.google.com/linux/chrome/deb/dists/stable/main/binary-amd64/Packages | \
     grep -A1 "Package: google-chrome-stable" | \
     awk '/Version/{print $2}' | \
     cut -d '-' -f1

Do not report updates for ChromeOS, Android or other platforms stable versions as updates here.

Flags in chrome-flags.conf with quotes (--user-agent="Mozilla/4.0 (compatible; MSIE 6.0b; Windows NT 5.1)") are not applied correctly. Instead, multiple tabs are opened ("(compatible;", "msie", "6.0b;", "windows", ...).

Suggestions for dependency updates:

• kwallet should be kwallet5 for now
• Add plasma-browser-integration as optional for integration with KDE
• Is kdialog still required for KDE file dialogs? At least it's not the case for KDE Wayland session (which uses portal)

Outdated now. I have built new one. Here is the PKGBUILD

# Maintainer: Christian Heusel <christian@heusel.eu>
# Contributor: Knut Ahlers <knut at ahlers dot me>
# Contributor: Det <nimetonmaili g-mail>
# Contributor: t3ddy, Lex Rivera aka x-demon, ruario

# Check for new Linux releases in: http://googlechromereleases.blogspot.com/search/label/Stable%20updates
# or use: $ curl -sSf https://dl.google.com/linux/chrome/deb/dists/stable/main/binary-amd64/Packages | grep -A1 "Package: google-chrome-stable" | awk '/Version/{print $2}' | cut -d '-' -f1

pkgname=google-chrome
pkgver=118.0.5993.88
pkgrel=1
pkgdesc="The popular web browser by Google (Stable Channel)"
arch=('x86_64')
url="https://www.google.com/chrome"
license=('custom:chrome')
depends=(
    'alsa-lib'
    'gtk3'
    'libcups'
    'libxss'
    'libxtst'
    'nss'
    'ttf-liberation'
    'xdg-utils'
)
optdepends=(
    'pipewire: WebRTC desktop sharing under Wayland'
    'kdialog: for file dialogs in KDE'
    'gnome-keyring: for storing passwords in GNOME keyring'
    'kwallet: for storing passwords in KWallet'
)
options=('!emptydirs' '!strip')
install=$pkgname.install
_channel=stable
source=("https://dl.google.com/linux/chrome/deb/pool/main/g/google-chrome-${_channel}/google-chrome-${_channel}_${pkgver}-1_amd64.deb"
    'eula_text.html'
    "google-chrome-$_channel.sh")
sha512sums=('cae6a5cd8632ad350b41f4dfaf80449e6cf19d0b02816b9a1600f54b15df2adf5c4ded3792bfbe3855fa11a79ea256622f50180aa3c6779cedd75a55e7a6da9d'
            'a225555c06b7c32f9f2657004558e3f996c981481dbb0d3cd79b1d59fa3f05d591af88399422d3ab29d9446c103e98d567aeafe061d9550817ab6e7eb0498396'
            'de02b498a4b5b93e21622c8dba57befe795d733a04656be911cc38e28bfef0e20470450f44be523bbde8d4de28f79c10434846ca01fc2a2f4e67707b79332f94')

package() {
    bsdtar -xf data.tar.xz -C "$pkgdir/"

    # Launcher
    install -m755 google-chrome-$_channel.sh "$pkgdir"/usr/bin/google-chrome-$_channel

    # Icons
    for i in 16x16 24x24 32x32 48x48 64x64 128x128 256x256; do
        install -Dm644 "$pkgdir"/opt/google/chrome/product_logo_${i/x*/}.png \
            "$pkgdir"/usr/share/icons/hicolor/$i/apps/google-chrome.png
    done

    # License
    install -Dm644 eula_text.html "$pkgdir"/usr/share/licenses/google-chrome/eula_text.html
    install -Dm644 "$pkgdir"/opt/google/chrome/WidevineCdm/LICENSE \
        "$pkgdir"/usr/share/licenses/google-chrome-$_channel/WidevineCdm-LICENSE.txt

    # Fix the Chrome desktop entry
    sed -i \
        -e "/Exec=/i\StartupWMClass=Google-chrome" \
        -e "s/x-scheme-handler\/ftp;\?//g" \
        "$pkgdir"/usr/share/applications/google-chrome.desktop

    # Remove the Debian Cron job, duplicate product logos and menu directory
    rm -r \
        "$pkgdir"/etc/cron.daily/ \
        "$pkgdir"/opt/google/chrome/cron/ \
        "$pkgdir"/opt/google/chrome/product_logo_*.{png,xpm} \
        "$pkgdir"/usr/share/menu/
}

Here is the .SRCINFO

pkgbase = google-chrome
    pkgdesc = The popular web browser by Google (Stable Channel)
    pkgver = 118.0.5993.88
    pkgrel = 1
    url = https://www.google.com/chrome
    install = google-chrome.install
    arch = x86_64
    license = custom:chrome
    depends = alsa-lib
    depends = gtk3
    depends = libcups
    depends = libxss
    depends = libxtst
    depends = nss
    depends = ttf-liberation
    depends = xdg-utils
    optdepends = pipewire: WebRTC desktop sharing under Wayland
    optdepends = kdialog: for file dialogs in KDE
    optdepends = gnome-keyring: for storing passwords in GNOME keyring
    optdepends = kwallet: for storing passwords in KWallet
    options = !emptydirs
    options = !strip
    source = https://dl.google.com/linux/chrome/deb/pool/main/g/google-chrome-stable/google-chrome-stable_118.0.5993.88-1_amd64.deb
    source = eula_text.html
    source = google-chrome-stable.sh
    sha512sums = cae6a5cd8632ad350b41f4dfaf80449e6cf19d0b02816b9a1600f54b15df2adf5c4ded3792bfbe3855fa11a79ea256622f50180aa3c6779cedd75a55e7a6da9d
    sha512sums = a225555c06b7c32f9f2657004558e3f996c981481dbb0d3cd79b1d59fa3f05d591af88399422d3ab29d9446c103e98d567aeafe061d9550817ab6e7eb0498396
    sha512sums = de02b498a4b5b93e21622c8dba57befe795d733a04656be911cc38e28bfef0e20470450f44be523bbde8d4de28f79c10434846ca01fc2a2f4e67707b79332f94

pkgname = google-chrome

117.0.5938.132-1 seems to have problems with mesa 23.2.1-1 (works fine with 23.1.8-1), on Intel irix graphics. Sample log, with repeated messages removed:

[5967:10:1004/104204.819729:ERROR:command_buffer_proxy_impl.cc(129)] ContextResult::kTransientFailure: Failed to send GpuControl.CreateCommandBuffer.
[5769:5769:1004/104204.948403:ERROR:gpu_process_host.cc(989)] GPU process exited unexpectedly: exit_code=139
[5967:10:1004/104205.573922:ERROR:command_buffer_proxy_impl.cc(321)] GPU state invalid after WaitForGetOff
setInRange.
[5967:10:1004/104205.573994:ERROR:grcontext_for_gles2_interface.cc(61)] Skia shader compilation error
------------------------
#version 100

precision highp float;
precision highp sampler2D;
uniform highp vec4 sk_RTAdjust;
uniform highp mat3 umatrix_S1_c0_c0;
attribute highp vec2 position;
attribute highp vec2 localCoord;
varying highp vec2 vTransformedCoords_4_S0;
void main() {
    gl_Position = vec4(position, 0.0, 1.0);
    {
        vTransformedCoords_4_S0 = (umatrix_S1_c0_c0 * vec3(localCoord, 1.0)).xy;
    }
    gl_Position = vec4(gl_Position.xy * sk_RTAdjust.xz + gl_Position.ww * sk_RTAdjust.yw, 0.0, gl_Position.w);
}

Apologies if this isn't the right place to report this; at the moment in the middle of a large project and can't determine whether chrome or mesa is at fault.

It might be a good idea to add NetworkManager and BlueZ as optional dependencies, as Chrom(e/ium) use their DBus APIs for geolocation and Bluetooth support respectively.

It seems that Google now has the correct latest version again, so presumably it was a temporary 'glitch'. Anyway this aur package is fine, and all seems well again.

@mike.cloaked The described method is still accurately describing this packages upstream. Strangely it seems like google has downgraded the version in the apt repo ... As I found no announcement nor complaints about major bugs or CVE's I just kept this package it as is, but if someone knows whats up please let me know! :)

Is there any other alternative way to query the current latest version direct from Google?