This builds correctly with libmupdf 1.26.2-1. Just added a sed line to update pdf_embedded_file_params and pdf_get_embedded_file_params to their current names.
# Maintainer: Florian Stecker <oss@florianstecker.net>
# Contributor: Sagnik Mandal <criticic>
# Contributor: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Eli Schwartz <eschwartz@archlinux.org>
# Contributor: earnestly
pkgname=llpp
pkgver=42
pkgrel=1
pkgdesc='opengl accelerated pdf viewer based on mupdf'
arch=('x86_64')
url=https://github.com/criticic/llpp
_commit=dbf07cf23e006d4bcb23469b41da50697c1907b8
license=('GPL3')
depends=('freetype2' 'gumbo-parser' 'jbig2dec' 'libgl' 'libjpeg' 'openjpeg2' 'libmupdf')
makedepends=('asciidoc' 'git' 'ocaml' 'ocaml-lablgl')
optdepends=('djvulibre: for llppac djvu conversion'
'ghostscript: for llppac ps, dvi, and djvu conversion'
'imagemagick: for llppac image conversion'
'inotify-tools: for the llpp.inotify autoreload wrapper'
'librsvg: for llppac svg conversion'
'unoconv: for llppac office conversion')
options=('!strip' '!debug')
source=("git+$url#commit=$_commit")
b2sums=('SKIP')
prepare() {
cd $pkgname
sed -i -e 's/pdf_get_embedded_file_params/pdf_get_filespec_params/' -e 's/pdf_embedded_file_params/pdf_filespec_params/' link.c
}
build() {
cd $pkgname
bash ./build.bash build
bash ./build.bash build doc
}
package() {
cd $pkgname
install -Dt "$pkgdir"/usr/bin build/llpp misc/llpp{.inotify,ac}
install -Dm644 -t "$pkgdir"/usr/share/applications misc/llpp.desktop
install -Dm644 -t "$pkgdir"/usr/share/man/man1 build/doc/*.1
}
Pinned Comments
stek commented on 2024-04-12 15:01 (UTC) (edited on 2024-04-12 15:07 (UTC) by stek)
If llpp doesn't start and instead produces an error like
or
this likely means that the version of libmupdf used to build llpp does not agree with the currently installed one.
This can be fixed by rebuilding llpp (with
makepkg -C
, or if you're using an AUR helper, whatever the "clean build" option is there). If this doesn't help, please leave a comment here or report upstream.cynik commented on 2022-09-18 07:05 (UTC)
I have updated it to my fork at: https://github.com/criticic/llpp