Arch Linux User Repository

If you encounter compilation errors, it may be caused by the rust version, please try to use devtools: https://wiki.archlinux.org/title/DeveloperWiki:Building_in_a_clean_chroot.

The latest version build status can refer to: https://build.archlinuxcn.org/packages/#/neovide-git

For anybody interested in fixing the lag issues before upstream PR 1870 merges, here is a patch you can apply with git am file.patch that will build from that PR instead of the default branch and run a bit faster!

From a79582f6c083ef0ade2b876507fdbfb7dc011f02 Mon Sep 17 00:00:00 2001
From: Caleb Maclennan <caleb@alerque.com>
Date: Thu, 15 Jun 2023 12:39:31 +0300
Subject: [PATCH] Apply PR 1870 with render loop fixes

Signed-off-by: Caleb Maclennan <caleb@alerque.com>
---
 .SRCINFO | 4 ++--
 PKGBUILD | 4 +++-
 2 files changed, 5 insertions(+), 3 deletions(-)

diff --git a/.SRCINFO b/.SRCINFO
index 43b1544..aa4d1fd 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,6 +1,6 @@
 pkgbase = neovide-git
    pkgdesc = No Nonsense Neovim Client in Rust
-   pkgver = 0.10.4.r17.gf412399
+   pkgver = 0.10.4.r43.g861fea2
    pkgrel = 1
    url = https://github.com/neovide/neovide
    arch = x86_64
@@ -17,7 +17,7 @@ pkgbase = neovide-git
    depends = neovim
    depends = sndio
    optdepends = vulkan-intel: vulkan support for intel
-   provides = neovide=0.10.4.r17.gf412399
+   provides = neovide=0.10.4.r43.g861fea2
    conflicts = neovide
    source = neovide::git+https://github.com/neovide/neovide.git
    sha256sums = SKIP
diff --git a/PKGBUILD b/PKGBUILD
index 0b8c370..bedcd4d 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -5,7 +5,7 @@

 pkgname=neovide-git
 _pkgname=${pkgname%-git}
-pkgver=0.10.4.r17.gf412399
+pkgver=0.10.4.r43.g861fea2
 pkgrel=1
 pkgdesc='No Nonsense Neovim Client in Rust'
 arch=(x86_64)
@@ -30,6 +30,8 @@ sha256sums=('SKIP')

 prepare() {
    cd "$_pkgname"
+   git fetch origin pull/1870/head
+   git checkout -b 1870 FETCH_HEAD
    sed -i -e '/^incremental/a opt-level = 3' Cargo.toml
    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
 }
-- 
2.41.0

Sure I can co-maintain. I just pushed the below patch.

Yes the stable Rust toolchain works for this project, and per Arch guidelines specifying that expertly helps several build scenarios.

@alerque It looks like neovide can already be compiled with stable toolchain, I think this patch makes sense. Can I add you as co-maintainer?

I'd like to suggest applying the following patch (can be done with git am file.patch). This includes a number of fixes from the Arch Rust package guidelines, some dependency and provide issues, takes care of the possible Rust toolchain issues for people that don't build in chroots, and also uses the same style as the official release package in [extra]. I know this might be your preferred coding style, but this makes it easy to diff and see what has changed between versions. This will also make it easy for me to have the stable builds up to date as soon as they are tagged.

From 195c11cfda076b43bf318a48ba2bd22c38e592f7 Mon Sep 17 00:00:00 2001
From: Caleb Maclennan <caleb@alerque.com>
Date: Thu, 15 Jun 2023 11:38:20 +0300
Subject: [PATCH] Fix Rust package guidelines and restyle matching official
 [extra] package

Signed-off-by: Caleb Maclennan <caleb@alerque.com>
---
 .SRCINFO | 18 +++++++--------
 PKGBUILD | 67 +++++++++++++++++++++++++++++++++-----------------------
 2 files changed, 49 insertions(+), 36 deletions(-)

diff --git a/.SRCINFO b/.SRCINFO
index 475746e..065c517 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,25 +1,25 @@
 pkgbase = neovide-git
    pkgdesc = No Nonsense Neovim Client in Rust
-   pkgver = 0.10.4.r6.g4b3c234
+   pkgver = 0.10.4.r17.gf412399
    pkgrel = 1
    url = https://github.com/neovide/neovide
    arch = x86_64
    license = MIT
-   makedepends = git
    makedepends = cargo
-   makedepends = gtk3
    makedepends = cmake
-   makedepends = sdl2
-   makedepends = make
+   makedepends = git
+   makedepends = gtk3
    makedepends = python
-   depends = neovim
+   makedepends = sdl2
    depends = fontconfig
    depends = freetype2
    depends = libglvnd
+   depends = neovim
    depends = sndio
-   provides = neovide
+   optdepends = vulkan-intel: vulkan support for intel
+   provides = neovide=0.10.4.r17.gf412399
    conflicts = neovide
-   source = neovide-git::git+https://github.com/Kethku/neovide
-   sha1sums = SKIP
+   source = neovide::git+https://github.com/neovide/neovide
+   sha256sums = SKIP

 pkgname = neovide-git
diff --git a/PKGBUILD b/PKGBUILD
index f09f8c2..96f277d 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,46 +1,59 @@
 # Maintainer: j4qfrost <j4qfrost at gmail dot com>
 # Maintainer: ptolemy753 <dsconce at protonmail dot com>
 # Maintainer: peeweep <peeweep at 0x0 dot ee>
+# Contributor: Caleb Maclennan <caleb@alerque.com>

 pkgname=neovide-git
-pkgver=0.10.4.r6.g4b3c234
+_pkgname=${pkgname%-git}
+pkgver=0.10.4.r17.gf412399
 pkgrel=1
 pkgdesc='No Nonsense Neovim Client in Rust'
-arch=('x86_64')
-url='https://github.com/neovide/neovide'
-license=('MIT')
-depends=('neovim' 'fontconfig' 'freetype2' 'libglvnd' 'sndio')
-makedepends=('git' 'cargo' 'gtk3' 'cmake' 'sdl2' 'make' 'python')
-provides=("neovide")
-conflicts=("neovide")
-source=("${pkgname}::git+${url}")
-sha1sums=('SKIP')
+arch=(x86_64)
+url="https://github.com/$_pkgname/$_pkgname"
+license=(MIT)
+depends=(fontconfig
+         freetype2
+         libglvnd
+         neovim
+         sndio)
+makedepends=(cargo
+             cmake
+             git
+             gtk3
+             python
+             sdl2)
+optdepends=('vulkan-intel: vulkan support for intel')
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+source=("$_pkgname::git+$url")
+sha256sums=('SKIP')

 pkgver() {
-  cd "${srcdir}/${pkgname}"
-  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+   cd "$_pkgname"
+   git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
 }

 prepare() {
-  cd "${srcdir}/${pkgname}"
-  sed -i -e '/^incremental/a opt-level = 3' Cargo.toml
+   cd "$_pkgname"
+   sed -i -e '/^incremental/a opt-level = 3' Cargo.toml
+   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
 }

 build() {
-  cd "${srcdir}/${pkgname}"
-  export CARGO_HOME="${srcdir}/${pkgname}/CARGO"
-  CFLAGS+=' -ffat-lto-objects'
-  cargo build --release --all-features
+   cd "$_pkgname"
+   export RUSTUP_TOOLCHAIN=stable
+   export CARGO_TARGET_DIR=target
+   CFLAGS+=' -ffat-lto-objects'
+   cargo build --frozen --release --all-features
 }

 package() {
-  install -Dm644 ${srcdir}/${pkgname}/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
-  install -Dm755 ${srcdir}/${pkgname}/target/release/neovide ${pkgdir}/usr/bin/neovide
-  install -Dm644 ${srcdir}/${pkgname}/assets/neovide.desktop ${pkgdir}/usr/share/applications/neovide.desktop
-  for px in 16 32 48 256; do
-    install -Dm644 "${srcdir}/${pkgname}/assets/neovide-${px}x${px}.png" \
-      "${pkgdir}/usr/share/icons/hicolor/${px}x${px}/apps/neovide.png"
-  done
+   cd "$_pkgname"
+   install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname"
+   install -Dm0644 -t "$pkgdir/usr/share/applications/" "assets/$_pkgname.desktop"
+   for px in 16 32 48 256; do
+       install -Dm0644 "assets/$_pkgname-${px}x${px}.png" \
+           "$pkgdir/usr/share/icons/hicolor/${px}x${px}/apps/$_pkgname.png"
+   done
+   install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
 }
-
-# vim: ts=2 sw=2 et:
-- 
2.41.0

I'm seeing a memory leak with the latest git version of neovide as compiled using this PKGBUILD, which is caused by the --all-features flag enabling the new profiling features.

I made an issue upstream (https://github.com/neovide/neovide/issues/1892) with the resolution being to not compile with profiling features unless you specifically want to profile the application, since it buffers all the data in memory.

This is easily fixed by simply removing the --all-features flag.

OK.

I think the URL should be updated to https://github.com/neovide/neovide.

@Revanee thanks for you patch!

I'm having an issue with the icon file names with package version 0.10.1.r16.gf7ad535. I fixed it with the following patch:

From 958d5388c0f31523503df0432c982a81bb0a5233 Mon Sep 17 00:00:00 2001
From: Hristo Kamenov <hkamenov123@gmail.com>
Date: Thu, 13 Apr 2023 12:58:07 +0200
Subject: [PATCH] fixed icon names

---
 PKGBUILD | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/PKGBUILD b/PKGBUILD
index b826c51..f9de423 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -38,8 +38,8 @@ package() {
   install -Dm755 ${srcdir}/${pkgname}/target/release/neovide ${pkgdir}/usr/bin/neovide
   install -Dm644 ${srcdir}/${pkgname}/assets/neovide.desktop ${pkgdir}/usr/share/applications/neovide.desktop
   for px in 16 32 48 256; do
-    install -Dm644 "${srcdir}/${pkgname}/assets/${pkgname}-${px}x${px}.png" \
-      "${pkgdir}/usr/share/icons/hicolor/${px}x${px}/apps/${pkgname}.png"
+    install -Dm644 "${srcdir}/${pkgname}/assets/neovide-${px}x${px}.png" \
+      "${pkgdir}/usr/share/icons/hicolor/${px}x${px}/apps/neovide.png"
   done
 }

-- 
2.40.0

@Mawkler Made a quick fix, tell me if the icon is not working yet.