Package Details: python-standardebooks 2.6.2-2

Git Clone URL: https://aur.archlinux.org/python-standardebooks.git (read-only, click to copy)
Package Base: python-standardebooks
Description: The toolset used to produce Standard Ebooks epub ebooks.
Upstream URL: https://standardebooks.org
Licenses: GPLv3
Submitter: nakano
Maintainer: nakano (standardebooks)
Last Packager: standardebooks
Votes: 1
Popularity: 0.000000
First Submitted: 2019-02-22 12:57 (UTC)
Last Updated: 2024-01-24 17:00 (UTC)

Dependencies (2)

Required by (0)

Sources (0)

Latest Comments

Auerhuhn commented on 2024-01-01 23:35 (UTC)

Hi @nakano and @standardebooks,

Here’s a PKGBUILD that fixes all known outstanding issues, including RFC0020 compliance, PEP 517 compliance, incorrect license identifier, incorrect arch entry, missing depends entries, and a /usr/bin/se executable:

# Python package author: Standard Ebooks <standardebooks@googlegroups.com>
# Maintainer: Tassos Natsakis <7712382@eipieq.com>
# Maintainer: Standard Ebooks <admin@standardebooks.org>
# Contributor: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=python-standardebooks
_name=tools
pkgver=2.6.1
pkgrel=3
pkgdesc="The toolset used to produce Standard Ebooks epub ebooks."
arch=(x86_64)
url="https://standardebooks.org"
license=(GPL3)
depends=(
  "java-runtime"
  "python-cairosvg"
  "python-chardet"
  "python-cssselect"
  "python-cssutils"
  "python-ftfy"
  "python-gitpython"
  "python-lxml"
  "python-natsort"
  "python-pillow"
  "python-psutil"
  "python-pyphen"
  "python-regex"
  "python-requests"
  "python-rich"
  "python-roman"
  "python-selenium"
  "python-setuptools"
  "python-smartypants"
  "python-tinycss2"
  "python-titlecase"
  "python-unidecode"
)
makedepends=("python-build" "python-installer" "python-wheel")

source=("${_name}-${pkgver}.tar.gz::https://github.com/standardebooks/tools/archive/refs/tags/${pkgver}.tar.gz")

sha512sums=("0ad4d17dfad6f91afbebda79e6cdb820d8dd332cf9581e015cd7d5f206a8d2264d50c1e2606781f6de062ac365da904b9e8e6d35d86448fd4a84606d467e6205")

prepare() {
  # Fix `importlib_resources` deprecation
  grep -lFR --include="*.py" "importlib_resources" "${_name}-${pkgver}" \
    | xargs -r -n 1 sed -i -e "s/importlib_resources/importlib.resources/g"
}

build() {
  cd "${_name}-${pkgver}"
  python -m build --wheel --no-isolation
}

package() {
  cd "${_name}-${pkgver}"
  python -m installer --destdir="$pkgdir" dist/*.whl
}

kseistrup commented on 2021-12-26 19:24 (UTC)

This PKGBUILD will install the se command to the correct location: https://gist.github.com/kseistrup/858b1dce41d24135b682ca73bcc0e1aa

It still doesn't have all the dependencies, but eventually it will get there.

macxcool commented on 2021-11-22 22:03 (UTC)

I agree with @kseitrup on both points. The binary should be symlinked to /usr/bin and at least the python libraries he listed (actually python-roman, python-importlib_resources, python-titlecase and python-gitpython as well) should be in depends.

kseistrup commented on 2021-04-19 09:03 (UTC)

The package has loads of dependencies, so I'm not sure the --no-deps is the best way to go. I had to manually install python-ftfy, python-tinycss2, and python-titlecase in order to just run the help command. All the dependencies in the setup.py file ought to be listed as dependencies for this package, IMHO.

kseistrup commented on 2021-04-19 08:48 (UTC)

Shouldn't the /usr/lib/python3.9/site-packages/bin/se command reside in /usr/bin (or at least be symlinked to that directory)?