Package Details: quickshell r484.aeb347b-1

Git Clone URL: https://aur.archlinux.org/quickshell.git (read-only, click to copy)
Package Base: quickshell
Description: Simple and flexbile QtQuick based desktop shell toolkit.
Upstream URL: https://quickshell.outfoxxed.me/
Keywords: bar hyprland qt qtquick wayland wlroots
Licenses: GPL
Submitter: entailzwrapped
Maintainer: entailzwrapped
Last Packager: entailzwrapped
Votes: 2
Popularity: 0.28
First Submitted: 2024-06-02 19:58 (UTC)
Last Updated: 2025-03-24 19:00 (UTC)

Pinned Comments

Latest Comments

entailzwrapped commented on 2025-03-24 19:18 (UTC)

Applied your patches @yvvki

yvvki commented on 2025-02-20 00:47 (UTC) (edited on 2025-02-20 00:51 (UTC) by yvvki)

Alternative package versioning and updated url, probably you can set the name to append -git for paru intergration.

diff --git a/PKGBUILD b/PKGBUILD
index d0b236e..2d946d6 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,13 +1,11 @@
 # Maintainer: Entailz <entail-wraps0r at icloud dot com>

 pkgname=quickshell
-pkgver=0.1.af14a41
+pkgver=r484.aeb347b
 pkgrel=1
 pkgdesc='Simple and flexbile QtQuick based desktop shell toolkit.'
 arch=(x86_64 aarch64)
-url='https://github.com/outfoxxed/quickshell'
-conflicts=("quickshell")
-provides=("quickshell")
+url='https://quickshell.outfoxxed.me/'
 options=(!strip)
 license=('GPL')
 depends=(
@@ -31,34 +29,34 @@ makedepends=(
   'pkgconf'
 )

-source=(
-  "git+https://github.com/outfoxxed/quickshell.git"
-
-)
-sha256sums=(
-  'SKIP'
-)
+source=(git+https://git.outfoxxed.me/$pkgname/$pkgname
+        quickshell-check.hook)
+sha256sums=('SKIP'
+            '8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083')
+b2sums=('SKIP'
+        'c729d8c05d0490eda0a4095d831f7fe4f2873debe0dd3dbb0de41a801ed652a885de7048cecc26eaddec9d22e68a7d00552ad3f3db96d80041671192faf0afe0')

 pkgver() {
   cd "$srcdir/quickshell"
-  printf "0.1.%s" "$(git rev-parse --short HEAD)"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
 }

 build() {
-  cd "${pkgname}"
+  cd $pkgname
   cmake -GNinja -B build \
     -DCMAKE_BUILD_TYPE="RelWithDebInfo" \
     -DCMAKE_INSTALL_PREFIX=/usr \
     -DDISTRIBUTOR="AUR (package: quickshell)" \
     -DDISTRIBUTOR_DEBUGINFO_AVAILABLE=NO \
-    -DINSTALL_QML_PREFIX=/lib/qt6/qml
+    -DINSTALL_QML_PREFIX=lib/qt6/qml

   cmake --build build
 }

 package() {
-  cd "${pkgname}"
+  install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
+
+  cd $pkgname
   DESTDIR=$pkgdir cmake --install build
-  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-  install -Dm644 "../../quickshell-check.hook" "$pkgdir/usr/share/libalpm/hooks/quickshell-check.hook"
+  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
 }

yvvki commented on 2025-02-16 06:48 (UTC) (edited on 2025-02-19 13:38 (UTC) by yvvki)

I think the hook is supposed to be included in the source, otherwise doing ../.. while building would break some wrapper like aura.

To be exact: build is failing with custom makepkg's SRCPKGDIST.

khing0_0 commented on 2025-02-11 09:05 (UTC) 

# Maintainer: Entailz <entail-wraps0r at icloud dot com>

_pkgname=quickshell
pkgname=${_pkgname}-git
pkgver=0.1.aeb347b
pkgrel=1
pkgdesc='Simple and flexbile QtQuick based desktop shell toolkit.'
arch=(x86_64 aarch64)
url='https://github.com/outfoxxed/quickshell'
conflicts=("quickshell")
provides=("quickshell")
options=(!strip)
license=('GPL')
depends=(
  'qt6-declarative'
  'qt6-base'
  'jemalloc'
  'qt6-svg'
  'libpipewire'
  'qt6-wayland'
  'wayland-protocols'
  'libxcb'
  'wayland'
  'cli11'
  'libdrm'
  'mesa'
  'google-breakpad'
)
makedepends=(
  'ninja'
  'cmake'
  'pkgconf'
)

source=(
  "git+https://github.com/outfoxxed/quickshell.git"

)
sha256sums=(
  'SKIP'
)

pkgver() {
  cd "$srcdir/${_pkgname}" || exit
  printf "0.1.%s" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${_pkgname}"
  cmake -GNinja -B build \
    -DCMAKE_BUILD_TYPE="RelWithDebInfo" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DDISTRIBUTOR="AUR (package: quickshell)" \
    -DDISTRIBUTOR_DEBUGINFO_AVAILABLE=NO \
    -DINSTALL_QML_PREFIX=/lib/qt6/qml

  cmake --build build
}

package() {
  cd "${_pkgname}"
  DESTDIR=$pkgdir cmake --install build
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
  install -Dm644 "../../quickshell-check.hook" "$pkgdir/usr/share/libalpm/hooks/quickshell-check.hook"
}

quickshell-git

unwitting commented on 2025-02-07 14:02 (UTC)

reinstalled, rebuild, but always same, keep telling me to update aur/quickshell 0.1.aeb347b-1 -> 0.1.af14a41-1

yvvki commented on 2025-02-04 10:55 (UTC)

I think this package should have a -git suffix. It kept telling me to update but it is on the last commit.