Arch Linux User Repository

I updated the PKGBUILD to include aarch64 it would be nice if you could update the package.

# Maintainer: Aikawa Yataro <aikawayataro at protonmail dot com>
# Contributor: Your Name <your email>

pkgname=sourcegit-bin
_name=${pkgname%-bin}
pkgver=2025.28
pkgrel=1
pkgdesc="GUI client for GIT users"
arch=('x86_64' 'aarch64')
url='https://github.com/sourcegit-scm/sourcegit'
license=('MIT')
provides=('sourcegit')
conflicts=('sourcegit')
depends=('git' 'xdg-utils')
optdepends=('git-credential-manager: third-party authentication support')
makedepends=('desktop-file-utils')

_debrev=1
source_x86_64=("https://github.com/sourcegit-scm/sourcegit/releases/download/v${pkgver}/${_name}_${pkgver}-${_debrev}_amd64.deb")
source_aarch64=("https://github.com/sourcegit-scm/sourcegit/releases/download/v${pkgver}/${_name}_${pkgver}-${_debrev}_arm64.deb")
source=("${_name}_${pkgver}-LICENSE::https://raw.githubusercontent.com/sourcegit-scm/sourcegit/v${pkgver}/LICENSE")

sha256sums=('401da433d52df8165d5afef3e4354f84ccc4beb67cdd74e2c483a9a1ae038ecb')
sha256sums_x86_64=('7f8df4712ded654b0088d5b16dae266f10ca8c8113dca16216218998234bc1f8')
sha256sums_aarch64=('496415edf301d38223d3dd5b71a8563533c2b2f0ea97da1622c48ad6ba2a675f')

prepare() {
    # The .deb file is just an 'ar' archive, extract it to get control.tar.* and data.tar.*
    local deb_file
    case "$CARCH" in
        "x86_64")
            deb_file="${_name}_${pkgver}-${_debrev}_amd64.deb"
            ;;
        "aarch64")
            deb_file="${_name}_${pkgver}-${_debrev}_arm64.deb"
            ;;
    esac
    bsdtar -xf "$srcdir/$deb_file"

    # Check for the data archive with either .gz or .xz compression and extract it
    if [ -f "data.tar.gz" ]; then
        bsdtar -xf data.tar.gz
    elif [ -f "data.tar.xz" ]; then
        bsdtar -xf data.tar.xz
    else
        echo "ERROR: Could not find data.tar.gz or data.tar.xz"
        return 1
    fi

    desktop-file-edit usr/share/applications/sourcegit.desktop \
        --set-icon=sourcegit --set-key=Exec --set-value=sourcegit
}

package() {
    install -d "$pkgdir/opt/$_name/"
    install -d "$pkgdir/usr/bin/"

    cp -r opt/sourcegit/* "$pkgdir/opt/$_name/"
    ln -s "/opt/$_name/$_name" "$pkgdir/usr/bin/$_name"

    install -Dm644 usr/share/icons/sourcegit.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/$_name.png"
    install -Dm644 usr/share/applications/sourcegit.desktop "$pkgdir/usr/share/applications/$_name.desktop"
    install -Dm644 "${_name}_${pkgver}-LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

Upstream re-released 2025.08, if you getting hash validation error do a clean build

sourcegit_2025.08-1_amd64.deb ... ÉCHEC

Not the same kind of error. Upstream re-released v2025.08 9 hours ago (package updated 11 hours ago) which is obviously bad thing to do. Will update it with new hashsums.

Same kind of error as nanoka previous week. Happens with sourcegit package too.

==> ATTENTION : Ignore la vérification des signatures PGP des fichiers sources.
==> Validation des fichiers source avec sha256sums…
    sourcegit_2025.08-1_amd64.deb ... ÉCHEC
    sourcegit_2025.08-LICENSE ... Réussite
==> ERREUR : Un ou plusieurs fichiers ne sont pas valides !
 -> error downloading sources: /home/petite_fleur/.cache/yay/sourcegit-bin 
         context: exit status 1 


:: (1/1) Parsing SRCINFO: sourcegit-bin
==> Création du paquet sourcegit-bin 2025.08-1 (lun. 10 mars 2025 13:55:10)
==> Vérification des dépendances pour l’exécution…
==> Vérification des dépendances pour la compilation…
==> Récupération des sources…
  -> sourcegit_2025.08-1_amd64.deb trouvé
  -> sourcegit_2025.08-LICENSE trouvé
==> Validation des fichiers source avec sha256sums…
    sourcegit_2025.08-1_amd64.deb ... ÉCHEC
    sourcegit_2025.08-LICENSE ... Réussite
==> ERREUR : Un ou plusieurs fichiers ne sont pas valides !
 -> error making: sourcegit-bin-exit status 1
 -> Failed to install the following packages. Manual intervention is required:
sourcegit-bin - exit status 1

Do a clean build, upstream package compression has changed again

@nanoka thanks for heads up, it's fixed now, I've added unique name for LICENSE file so this will not happen again

==> Making package: sourcegit-bin 2025.07-1 (Mon 03 Mar 2025 05:05:48 PM +07)
==> Checking runtime dependencies...
==> Checking buildtime dependencies...
==> Retrieving sources...
  -> Found sourcegit_2025.07-1_amd64.deb
  -> Found LICENSE
==> Validating source files with sha256sums...
    sourcegit_2025.07-1_amd64.deb ... Passed
    LICENSE ... FAILED
==> ERROR: One or more files did not pass the validity check!
:: Unable to build sourcegit-bin - makepkg exited with code: 1

I've decided to make git-credential-manager an optional dependency this update because it's only needed when using user:password authentication on third-party resources (like GitHub), but if you're using an ssh key, this is completely avoided.

Good catch, fixed it

deb now use zstd, so in prepare function, the data.tar.xz should be data.tar.zst