Package Details: libmagick6 6.9.13.35-1

Git Clone URL: https://aur.archlinux.org/imagemagick6.git (read-only, click to copy)
Package Base: imagemagick6
Description: An image viewing/manipulation program (legacy 6.9.13-* series; library)
Upstream URL: https://legacy.imagemagick.org/
Keywords: ImageMagick imagemagick6
Licenses: custom
Submitter: arojas
Maintainer: None
Last Packager: envolution
Votes: 10
Popularity: 0.000000
First Submitted: 2021-01-29 14:32 (UTC)
Last Updated: 2025-12-08 12:31 (UTC)

Latest Comments

1 2 3 4 5 6 .. 15 Next › Last »

chicagomint commented on 2026-08-01 20:08 (UTC) 

# Maintainer: envolution 
# Contributor: chicagomint <chicagominted at gmail dot com>
# Contributor: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Xuanrui Qi <me@xuanruiqi.com>
# Contributor: bartus <arch-user-repoᘓbartus.33mail.com>
# Contributor: Eric Bélanger <eric@archlinux.org>
# shellcheck shell=bash disable=SC2034,SC2154

pkgbase=imagemagick6
pkgname=libmagick6
pkgver=6.9.13.54
_pkgver="${pkgver%.*}-${pkgver##*.}"
pkgrel=1
pkgdesc="An image viewing/manipulation program (legacy 6.9.13-* series)"
url="https://legacy.imagemagick.org/"
arch=('x86_64')
license=('custom')
depends=(
  'fontconfig'
  'lcms2'
  'liblqr'
  'libltdl'
  'libpng'
  'libraqm'
  'libxext'
  'libxml2'
)
makedepends=(
  'chrpath'
  'djvulibre'
  #  'ghostpcl'
  'ghostscript'
  #  'ghostxps'
  'glu'
  'jbigkit'
  'libheif'
  'libjxl'
  'libraw'
  'librsvg'
  'libwebp'
  'libwmf'
  'libzip'
  'ocl-icd'
  'opencl-headers'
  'openexr'
  'openjpeg2'
)
checkdepends=(
  'gsfonts'
  'ttf-dejavu'
)
source=("https://download.imagemagick.org/archive/ImageMagick-${_pkgver}.tar.gz"{,.asc}
  'arch-fonts.diff')
sha256sums=('dd8c8e2ef1c277e8e5b374d6112cabc766ab89fef035da46e00f4b73cf371b81'
            'SKIP'
            'a85b744c61b1b563743ecb7c7adad999d7ed9a8af816650e3ab9321b2b102e73')
validpgpkeys=('D8272EF51DA223E4D05B466989AB63D48277377A') # Lexie Parsimoniae (ImageMagick code signing key) <lexie.parsimoniae@imagemagick.org>

shopt -s extglob

prepare() {
  mkdir -p binpkg/usr/lib/pkgconfig {binpkg,docpkg}/usr/share

  cd "ImageMagick-${_pkgver}"

  # Fix up typemaps to match our packages, where possible
  patch -p1 -i ../arch-fonts.diff
}

build() {
  cd "ImageMagick-${_pkgver}"
  unset PERL5LIB PERL_LOCAL_LIB_ROOT PERL_MB_OPT PERL_MM_OPT
  ./configure \
    PKG_CONFIG="/usr/bin/env PKG_CONFIG_PATH=/usr/lib/$pkgbase/pkgconfig pkg-config" \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-shared \
    --disable-static \
    --with-dejavu-font-dir=/usr/share/fonts/TTF \
    --with-gs-font-dir=/usr/share/fonts/gsfonts \
    PSDelegate=/usr/bin/gs \
    XPSDelegate=/usr/bin/gxps \
    PCLDelegate=/usr/bin/gpcl6 \
    --enable-hdri \
    --enable-opencl \
    --without-gslib \
    --with-djvu \
    --with-jxl \
    --with-lqr \
    --with-modules \
    --with-openexr \
    --with-openjp2 \
    --with-perl \
    --with-perl-options=INSTALLDIRS=vendor \
    --with-rsvg \
    --with-webp \
    --with-wmf \
    --with-xml \
    --without-autotrace \
    --without-dps \
    --without-fftw \
    --without-fpx \
    --without-gcc-arch \
    --without-gvc
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() (
  cd "ImageMagick-${_pkgver}"
  unset PERL5LIB PERL_LOCAL_LIB_ROOT PERL_MB_OPT PERL_MM_OPT
  ulimit -n 4096
  make check || :
)

package_libmagick6() {
  pkgdesc="${pkgdesc/)/; library)}"
  optdepends=('ghostscript: PS/PDF support'
    'libheif: HEIF support'
    'libjxl: JPEG XL support'
    'libraw: DNG support'
    'librsvg: SVG support'
    'libwebp: WEBP support'
    'libwmf: WMF support'
    'libxml2: Magick Scripting Language'
    'ocl-icd: OpenCL support'
    'openexr: OpenEXR support'
    'openjpeg2: JPEG2000 support'
    'djvulibre: DJVU support'
    'pango: Text rendering')
  options=('!emptydirs' 'libtool')
  backup=(etc/ImageMagick-6/{coder,colors,delegates,log,magic,mime,policy,quantization-table,thresholds,type,type-{dejavu,ghostscript}}.xml)

  cd "ImageMagick-${_pkgver}"
  make DESTDIR="$pkgdir" install pkgconfigdir="/usr/lib/$pkgbase/pkgconfig"

  rm "$pkgdir"/etc/ImageMagick-6/type-{apple,urw-base35,windows}.xml
  rm "$pkgdir"/usr/lib/*.la

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE NOTICE

  # Drop tools
  cd ../binpkg
  mv "$pkgdir/usr/bin" usr/
  mv "$pkgdir/usr/lib/perl5" usr/lib/
  mv "$pkgdir/usr/share/man" usr/share/

  # Harden security policy https://bugs.archlinux.org/task/62785
  sed -e '/<\/policymap>/i \ \ <policy domain="delegate" rights="none" pattern="gs" \/>' -i \
    "$pkgdir"/etc/ImageMagick-6/policy.xml
}
# vim:set ts=2 sw=2 et:

chicagomint commented on 2026-08-01 20:07 (UTC) (edited on 2026-08-01 20:15 (UTC) by chicagomint)

Here is an updated PKGBUILD file supporting up to libmagick6-6.9.13.54:

# Maintainer: envolution 
# Contributor: chicagomint <chicagominted at gmail dot com>
# Contributor: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Xuanrui Qi <me@xuanruiqi.com>
# Contributor: bartus <arch-user-repoᘓbartus.33mail.com>
# Contributor: Eric Bélanger <eric@archlinux.org>
# shellcheck shell=bash disable=SC2034,SC2154

pkgbase=imagemagick6
pkgname=libmagick6
pkgver=6.9.13.54
_pkgver="${pkgver%.*}-${pkgver##*.}"
pkgrel=1
pkgdesc="An image viewing/manipulation program (legacy 6.9.13-* series)"
url="https://legacy.imagemagick.org/"
arch=('x86_64')
license=('custom')
depends=(
  'fontconfig'
  'lcms2'
  'liblqr'
  'libltdl'
  'libpng'
  'libraqm'
  'libxext'
  'libxml2'
)
makedepends=(
  'chrpath'
  'djvulibre'
  #  'ghostpcl'
  'ghostscript'
  #  'ghostxps'
  'glu'
  'jbigkit'
  'libheif'
  'libjxl'
  'libraw'
  'librsvg'
  'libwebp'
  'libwmf'
  'libzip'
  'ocl-icd'
  'opencl-headers'
  'openexr'
  'openjpeg2'
)
checkdepends=(
  'gsfonts'
  'ttf-dejavu'
)
source=("https://download.imagemagick.org/archive/ImageMagick-${_pkgver}.tar.gz"{,.asc}
  'arch-fonts.diff')
sha256sums=('dd8c8e2ef1c277e8e5b374d6112cabc766ab89fef035da46e00f4b73cf371b81'
            'SKIP'
            'a85b744c61b1b563743ecb7c7adad999d7ed9a8af816650e3ab9321b2b102e73')
validpgpkeys=('D8272EF51DA223E4D05B466989AB63D48277377A') # Lexie Parsimoniae (ImageMagick code signing key) <lexie.parsimoniae@imagemagick.org>

shopt -s extglob

prepare() {
  mkdir -p binpkg/usr/lib/pkgconfig {binpkg,docpkg}/usr/share

  cd "ImageMagick-${_pkgver}"

  # Fix up typemaps to match our packages, where possible
  patch -p1 -i ../arch-fonts.diff
}

build() {
  cd "ImageMagick-${_pkgver}"
  unset PERL5LIB PERL_LOCAL_LIB_ROOT PERL_MB_OPT PERL_MM_OPT
  ./configure \
    PKG_CONFIG="/usr/bin/env PKG_CONFIG_PATH=/usr/lib/$pkgbase/pkgconfig pkg-config" \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-shared \
    --disable-static \
    --with-dejavu-font-dir=/usr/share/fonts/TTF \
    --with-gs-font-dir=/usr/share/fonts/gsfonts \
    PSDelegate=/usr/bin/gs \
    XPSDelegate=/usr/bin/gxps \
    PCLDelegate=/usr/bin/gpcl6 \
    --enable-hdri \
    --enable-opencl \
    --without-gslib \
    --with-djvu \
    --with-jxl \
    --with-lqr \
    --with-modules \
    --with-openexr \
    --with-openjp2 \
    --with-perl \
    --with-perl-options=INSTALLDIRS=vendor \
    --with-rsvg \
    --with-webp \
    --with-wmf \
    --with-xml \
    --without-autotrace \
    --without-dps \
    --without-fftw \
    --without-fpx \
    --without-gcc-arch \
    --without-gvc
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() (
  cd "ImageMagick-${_pkgver}"
  unset PERL5LIB PERL_LOCAL_LIB_ROOT PERL_MB_OPT PERL_MM_OPT
  ulimit -n 4096
  make check || :
)

package_libmagick6() {
  pkgdesc="${pkgdesc/)/; library)}"
  optdepends=('ghostscript: PS/PDF support'
    'libheif: HEIF support'
    'libjxl: JPEG XL support'
    'libraw: DNG support'
    'librsvg: SVG support'
    'libwebp: WEBP support'
    'libwmf: WMF support'
    'libxml2: Magick Scripting Language'
    'ocl-icd: OpenCL support'
    'openexr: OpenEXR support'
    'openjpeg2: JPEG2000 support'
    'djvulibre: DJVU support'
    'pango: Text rendering')
  options=('!emptydirs' 'libtool')
  backup=(etc/ImageMagick-6/{coder,colors,delegates,log,magic,mime,policy,quantization-table,thresholds,type,type-{dejavu,ghostscript}}.xml)

  cd "ImageMagick-${_pkgver}"
  make DESTDIR="$pkgdir" install pkgconfigdir="/usr/lib/$pkgbase/pkgconfig"

  rm "$pkgdir"/etc/ImageMagick-6/type-{apple,urw-base35,windows}.xml
  rm "$pkgdir"/usr/lib/*.la

  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE NOTICE

  # Drop tools
  cd ../binpkg
  mv "$pkgdir/usr/bin" usr/
  mv "$pkgdir/usr/lib/perl5" usr/lib/
  mv "$pkgdir/usr/share/man" usr/share/

  # Harden security policy https://bugs.archlinux.org/task/62785
  sed -e '/<\/policymap>/i \ \ <policy domain="delegate" rights="none" pattern="gs" \/>' -i \
    "$pkgdir"/etc/ImageMagick-6/policy.xml
}
# vim:set ts=2 sw=2 et:

xxxxme commented on 2026-05-30 18:30 (UTC) (edited on 2026-05-30 18:31 (UTC) by xxxxme)

Version 6.9.13.49 is available. Here's a PKGBUILD that works for me: https://dpaste.com/3UU8JZQ5J Note the slightly modified download URL: now using imagemagick.org/archive This does not include oxidative's suggestion, so if you need that you'll have to add it yourself.

oxidative commented on 2026-03-06 16:31 (UTC)

Add this to the end of the prepare() method of the PKGBUILD:

sed -i 's/const int offset)/const long long offset)/' coders/dng.c

Bumping the version to 6.9.13.40 also works then.

carlosnewmusic commented on 2026-02-07 10:15 (UTC) (edited on 2026-02-22 15:59 (UTC) by carlosnewmusic)

build error https://pastes.io/imagemagic

jsimon0 commented on 2026-02-05 14:30 (UTC)

I have 6.9.13.35-1 installed but recompiling it results in this error as well.

emceebois commented on 2026-02-05 14:20 (UTC)

Getting the following build error:

coders/dng.c: In function 'ReadDNGImage':
coders/dng.c:485:43: error: passing argument 2 of 'libraw_set_dataerror_handler' from incompatible pointer type [-Wincompatible-pointer-types]
  485 |     libraw_set_dataerror_handler(raw_info,LibRawDataError,exception);
      |                                           ^~~~~~~~~~~~~~~
      |                                           |
      |                                           void (*)(void *, const char *, const int)
In file included from coders/dng.c:77:
/usr/include/libraw/libraw.h:136:75: note: expected 'data_callback' {aka 'void (*)(void *, const char *, const long long int)'} but argument is of type 'void (*)(void *, const char *, const int)'
  136 |   DllDef void libraw_set_dataerror_handler(libraw_data_t *, data_callback func,
      |                                                             ~~~~~~~~~~~~~~^~~~
coders/dng.c:331:13: note: 'LibRawDataError' declared here
  331 | static void LibRawDataError(void *data,const char *magick_unused(file),
      |             ^~~~~~~~~~~~~~~
In file included from /usr/include/libraw/libraw.h:78:
/usr/include/libraw/libraw_types.h:151:18: note: 'data_callback' declared here
  151 |   typedef void (*data_callback)(void *data, const char *file, const INT64 offset);
      |                  ^~~~~~~~~~~~~
make[1]: *** [Makefile:8135: coders/dng_la-dng.lo] Error 1
make[1]: Leaving directory '/home/user/.cache/yay/imagemagick6/src/ImageMagick-6.9.13-35'
make: *** [Makefile:5713: all] Error 2
==> ERROR: A failure occurred in build().
    Aborting...
 -> error making: imagemagick6-exit status 4
 -> Failed to install the following packages. Manual intervention is required:
libmagick6 - exit status 4

1 2 3 4 5 6 .. 15 Next › Last »