Arch Linux User Repository

@Mar0xy Ahh, my bad. The mail was blocked by Yandex spam filter.

Sounds good. If you need any help please let me/us know. :)

@fabiscafe Thanks for the updated PKGBUILD.

I never really dealt with an PKGBUILD so this was my first time which is why it was mainly a bit jank also I can confirm that the contact email is indeed functional as I use it on all git related sites aswell as for business.

the issue with the git tag was the fact that I never dealt with git urls that much so I didn't know that was a function.

Anyways, I will update the PKGBUILD with the next version release which is planned for tomorrow currently.

Cheers

Hi. Thanks for the PKGBUILD. I changed it a bit. Most of the changes are style/format changes. Some do fix up things, like you don't need a provides line, as your packages always provides itself and some other minor things I could not understand. For example the line

install -dm755 "${pkgdir}/usr/bin" "an-anime-game-launcher"

or why you do

cd "$srcdir/an-anime-game-launcher"
git checkout tags/${pkgver}

makepkg does support to pull a tag/commit directly.

Your contacts info mail address also seems to be broken. The PKGBUILD is here:

# Maintainer: Marie Piontek <marie@kaifa.ch>

pkgname=an-anime-game-launcher
pkgver=1.6.0
pkgrel=2
pkgdesc="An Launcher for a specific anime game written in Electron with auto-patching and playtime tracking function"
url="https://notabug.org/nobody/an-anime-game-launcher"
arch=("x86_64")
license=("GPL3")
depends=(
    "electron"
    "git"
    "tar"
    "unzip"
    "xdelta3"
)
makedepends=(
    "git"
    "nodejs-lts-gallium"
    "npm"
)
optdepends=(
    "gamemode: Game Optimization"
    "mangohud: Required if you want to check FPS"
    "reshade-shaders-git: Required by vkBasalt config files (install this and vkbasalt)"
    "switcheroo-control: Hybrid GPU Support"
    "vkbasalt: Required to use custom shaders (install this and reshade-shaders-git)"
)
source=(
    "git+${url}.git#tag=${pkgver}"
    "an-anime-game-launcher.desktop"
    "an-anime-game-launcher.sh"
)
md5sums=(
    'SKIP'
    '44b5730fe1a5cf22d7be6e3bf717ea0f'
    '8b875e8115a3b80f9964dc66ddf46a9a'
)

prepare() {
    electronDist="/usr/lib/electron"
    electronVer="$(electron --version | tail -c +2)"

    sed -i '/"electron":/d' "${pkgname}/package.json"
}

build() {
    cd "${pkgname}"
    HOME="${srcdir}/.electron-gyp" npm install --cache "${srcdir}/npm-cache"
    npm run dev
    ./node_modules/.bin/electron-builder -l dir \
        -c.electronDist=${electronDist} \
        -c.electronVersion=${electronVer}
}

package() {
    cd "${pkgname}"
    install -dm755 "${pkgdir}/usr/lib/${pkgname}"
    cp -dr --no-preserve=ownership dist/linux-unpacked/resources/* "${pkgdir}/usr/lib/${pkgname}/"

    install -Dm644 public/images/icons/256x256.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
    install -Dm755 "${srcdir}/an-anime-game-launcher.sh" "${pkgdir}/usr/bin/${pkgname}"
    install -Dm644 "${srcdir}/an-anime-game-launcher.desktop" -t "${pkgdir}/usr/share/applications"
}